const byte prog_version = 0x05

include f452_20
include jdelay
include jpic16

ADCON1 = 0b_0000_0110

var volatile bit CTS is pin_c5
var volatile bit CTS_direction is pin_c5_direction

CTS = low
CTS_direction = output
CTS = low

include ./boards/whack452
include console
include ./javi_lib/i32
include ./javi_lib/i16
include ./javi_lib/pic18_pointers
include ram

const debug_mode = true

LoadPointer_0 ( MYIP )
MemNext = 10
MemNext = 0
MemNext = 0
MemNext = 11

-- telnet tcp "port" we are listening on.
const telnet_port = 23

-- http tcp "port" we are listening on.
const http_port = 80

-- tcp parameters. tune to suit.
const tcp_maxsegsize = 800
const tcp_window = ( 2 * tcp_maxsegsize )

LoadPointer_0 ( MYMAC )
MemNext = 0x00
MemNext = 0xD0
MemNext = 0x00
MemNext = 0x02
MemNext = 0x02
MemNext = 0x02

include ./tcpip/chksum
include ./boards/ne2000
include ./tcpip/arp
include ./tcpip/ip
include ./tcpip/icmp
include ./tcpip/udp
include ./tcpip/tcp
include ./tcpip/tcpapi
include telnet
include web
include http

procedure sign_on is
  delay_1ms ( 250 )
  f452_serial_setup
  delay_1ms ( 250 )
  putc = 13
  putc = 10
  putc = 13
  putc = 10
  putc = "P"
  putc = "0"
  putc = "5"
  putc = " "
  putc = "v"
  putc = " "
  putc = hex_to_ascii (prog_version >> 4)
  putc = "."
  putc = hex_to_ascii (prog_version & 0x0f)
  putc = 13
  putc = 10
  delay_1ms ( 250 )
end procedure

init_board

for 10 loop
  toggle_led
  delay_1ms ( 100 )
  toggle_led
  delay_1ms ( 100 )
end loop

sign_on

net_init
tcp_init

forever loop
  tcp_yield
  http_task(http_conn)
  telnet_task(telnet_conn)
end loop